SubversionのAuto-versioningのGitによる実装
#draft
Requirements
git-js(高速化？ts による実装？)
- Semantic Release による Semantic Versioning - Semantic Versioning の仕様をスクラッチする(一部のみ)
- 権限管理(とユーザ認証)は Nginx 側で行い、Rust では Git の auto-versioning のみを行う - Rust で認証から全て行う
## websocket を用いてソケット通信を行う
実装
Rust 側の処理
-
websocket でユーザリポジトリの path を nginx へ知らせる
- redirect response を返して path の位置にリダイレクトする
-
ディレクトリを監視して変更があった場合は自動的に commit, push を行う
-
toml でリポジトリとユーザの対応やその他設定を明示する
Auto-versioning architecture
git clone --bare でサーバモードで動かす(リモートリポジトリでも可能そう)-
基本的に Semantic Versioning の仕様書に従う
$
Semantic versioing Spec
#draft #BNF
Semantic Versioning 2.0.0
BNF
<valid semver> ::= <version core>
| <version core> "-" <pre-release>
| <version core> "+" <build>
| <version core> "-" <pre-release> "+" <build>
<version core> ::= <major> "." <minor> "." <patch>
<major> ::= <numeric identifier>
<minor> ::= <numeric identifier>
<patch> ::= <numeric identifier>
<pre-release> ::= <dot-separated pre-release identifiers>
<dot-separated pre-release identifiers> ::= <pre-release identifier>
| <pre-release identifier> "." <dot-separated pre-release identifiers>
<build> ::= <dot-separated build identifiers>
<dot-separated build identifiers> ::= <build identifier>
| <build identifier> "." <dot-separated build identifiers>
<pre-release identifier> ::= <alphanumeric identifier>
| <numeric identifier>
<build identifier> ::= <alphanumeric identifier>
| <digits>
<alphanumeric identifier> ::= <non-digit>
| <non-digit> <identifier characters>
| <identifier characters> <non-digit>
| <identifier characters> <non-digit> <identifier characters>
<numeric identifier> ::= "0"
| <positive digit>
| <positive digit> <digits>
<identifier characters> ::= <identifier character>
| <identifier character> <identifier characters>
<identifier character> ::= <digit>
| <non-digit>
<non-digit> ::= <letter>
| "-"
<digits> ::= <digit>
| <digit> <digits>
<digit> ::= "0"
| <positive digit>
<positive digit> ::= "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"
<letter> ::= "A" | "B" | "C" | "D" | "E" | "F" | "G" | "H" | "I" | "J"
| "K" | "L" | "M" | "N" | "O" | "P" | "Q" | "R" | "S" | "T"
| "U" | "V" | "W" | "X" | "Y" | "Z" | "a" | "b" | "c" | "d"
| "e" | "f" | "g" | "h" | "i" | "j" | "k" | "l" | "m" | "n"
| "o" | "p" | "q" | "r" | "s" | "t" | "u" | "v" | "w" | "x"
| "y" | "z"